[daip] Polarization Calibration
Doug Roberts
droberts.archive at gmail.com
Thu Nov 14 20:21:27 EST 2013
Hi Eric,
You are right. My email had the wide parallactic angle coverage
calibrator and known polarized source (3C286) transposed as you found
out! Sorry, about the confusion.
I understand your point that the continuum solution is redundent if the
spectral solution has sufficient S/N. But nothing would be wrong to do
the continuum one first followed by the spectral solution.
It looks like the cookbook has the continuum solutions for PCAL/RLDIF
followed by the spectral ones
(http://www.aips.nrao.edu/CookHTML/CookBookse152.html#x186-423000E.7).
Maybe that was meant to be either or?
I'm attaching my RUN file that defined EVLACAL (which I run on older VLA
data two). Almost all of our data I'm reducing this way is high
frequency. If you wouldn't mind looking it over to make sure I'm using
the polarization tasks properly I'd really appreciate it.
Thanks!
Doug
On 11/13/2013 2:52 PM, Eric Greisen wrote:
> Doug Roberts wrote:
>> Hi Eric,
>>
>> I have a pretty complex pipeline calibration script that I'd like to
>> run past you to make sure I'm doing polarization calibration
>> correctly. The script does Stokes I as well as polarization
>> calibration for our Galactic center projects. I'm using RLDLY, PCAL
>> and RLDIF. One question before I send the the big script for review
>> is about the ordering. In the documentation for spectral
>> polarization calibration to to the following steps:
>>
>> 1. RLDLY
>> 2. PCAL on 3C286 - CONT
>> 3. RLDIF using calibrator observed throughout run for parallactic
>> angle coverage - CONT
>> 4. PCAL - SPECTRAL
>> 5. RLDIF - SPECTRAL
>>
>> My script does the following
>>
>> 1. RLDLY
>> 2. PCAL on 3C286 - CONT
>> 3. PCAL - SPECTRAL
>> 4. RLDIF using calibrator observed throughout run for parallactic
>> angle coverage - CONT
>> 5. RLDIF - SPECTRAL
>>
>> Are these equivalant or should I do all the continuum before doing
>> the line polarization?
>>
>> Thanks in advance!
>> Doug
>>
>>
>
> I am a little perplexed by these. Normally PCAL is run on the source
> with the wide parallactic angle coverage (and unknown polarization)
> while RLDIF is run on 3C286 because its polarization angle is
> essentially constant and well known. RLDIF is also usually run only
> on a single scan, if it is long enough to have decent S/N. If one is
> going to do the SPECTRAL solution, then the continuum solution has
> little value other than confirming that the spectral solution is not
> crazy.
>
>
> Eric Greisen
-------------- next part --------------
*
* Do all calibration for EVLA data
*
$ Doug Roberts
$ Version 1.7
$ 2013.11.12
$
$ Change Log:
$ 1.7:
$ - Set BCHAN/ECHAN for RLDIF
$ - Set DOAPPLY for continuum run of RLDIF which will increment CL tables
$ - Apply bandpass calibration for continuum averages in PCAL
$
$---------------------------------------------------
*
* Define Proceedure
*
PROC HFDUMMY
STRING*12 HF_MULTIN
STRING*6 HF_MULTIC
STRING*16 HF_PRIMCL
STRING*16 HF_PHASC1
STRING*16 HF_PHASC2
STRING*16 HF_BPCAL(5)
STRING*16 HF_SRC
STRING*12 HF_OUTN
STRING*6 HF_CALCO
SCALAR HF_SOLINT
SCALAR HF_SOLSUB
SCALAR HF_REFANT
SCALAR HF_RECINT
SCALAR HF_SRCFLX
SCALAR HF_DOIMAG
SCALAR HF_CELL
SCALAR HF_IMSIZE
SCALAR HF_NEGCC
SCALAR HF_NITER
SCALAR HF_DOPCAL
SCALAR HF_DOBP
SCALAR HF_ANGEXP
SCALAR HF_CLSMO
SCALAR HF_UVRANG
SCALAR HF_CUVRAN
SCALAR HF_USEALL
SCALAR HF_AMPSC
SCALAR HF_BCHAN
SCALAR HF_ECHAN
SCALAR HF_BIF
SCALAR HF_EIF
SCALAR HF_DEBUG
FINISH
PROC EVLACAL
*
* == 1 Reset Adverbs ==
*
print '*** 1 RESETTING ADVERBS ***'
tput EVLACAL
clr2n
calcode ''
stokes ''
cmodel ''
antenn 0
doband -1
flux 0
ncomp 0
timer 0
indi 1
outdi 1
outse 0
outcl ''
bif 0
eif 0
uvrang 0
bmaj 0
bmin 0
bpa 0
dopol -1
cutoff 0
aparm 0
bparm 0
cparm 0
snver 0
docal 0
outver 0
grchan 0
ichansel 0
bchan 0
echan 0
pdver 0
bpver 0
doapply 0
smodel 1 0
*
* == 2 Reset fluxes, remove old calibration tables ==
*
print '*** 2 RESETTING FLUXES, REMOVE CALIBRATION TABLES ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
inext 'bp'
inver -1
extd
inext 'sn'
inver -1
extd
inext 'pd'
inver -1
extd
inext 'cp'
inver -1
extd
inext 'cl'
inver 2
extd
inver 3
extd
inver 4
extd
inver 5
extd
inver 6
extd
inver 7
extd
source ''
optype 'REJY'
go setjy
wait setjy
*
* == 3 VLANT: correcting for changes in antenna position
*
$ print '*** 3 VLANT: CORRECTING FOR CHANGES IN ANTENNA POSITION ***'
$ inna HF_MULTIN
$ incl HF_MULTIC
$ inse 1
$ gainver 1
$ go vlant
$ wait vlant
*
* == 4 SETJY: primary flux calibrator ==
*
print '*** 4 SETJY ON PRIMARY FLUX CALIBRATOR ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
bif HF_BIF
eif HF_EIF
source HF_PRIMCL ''
optype 'calc'
go setjy
wait setjy
IF HF_DEBUG = 1 THEN
read i
END
*
* == 5 Do Bandpass Calibration ==
*
IF HF_DOBP = 1 THEN
print '*** 5 DOING BANDPASS CALIBRATION ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
bif HF_BIF
eif HF_EIF
cals HF_BPCAL
solint 0
docal -1
$ antenn 0
refant HF_REFANT
soltype 'L1R'
ichansel HF_BCHAN HF_ECHAN 1 0
go bpass
wait bpass
IF HF_DEBUG = 1 THEN
read i
END
* Reset adverbs
ichansel 0
ELSE
print '*** 5 SKIPPING BANDPASS CALIBRATION ***'
END
*
* == 6 CALIB: Calibrate phases before *real* calibration (SN=1) ==
*
print '*** 6 CALIBRATE PHASES BEFORE *REAL* CALIBRATION (SN=1) ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
cals HF_PRIMCL HF_PHASC1 HF_PHASC2 ''
solint 5/60
docal 2
gainuse 1
snver 1
solmod 'p'
refant HF_REFANT
soltype 'L1R'
$ aparm 5 0 0 0 0 0 4 0
$ aparm 4 0 0 0 0 0 3 0
aparm 4 0 0 0 0 0 4 0
bif HF_BIF
eif HF_EIF
IF HF_DOBP = 1 THEN
doband 3
ELSE
doband -1
END
go calib
wait calib
IF HF_DEBUG = 1 THEN
read i
END
*
* == 7 CLCAL: Apply phase calibration ==
*
print '*** 7 APPLY PHASE CALIBRATION ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
source ''
cals HF_PRIMCL HF_PHASC1 HF_PHASC2 ''
opcode 'cali'
interpol '2pt'
snver 1
inver 1
gainver 1
gainuse 2
bif HF_BIF
eif HF_EIF
refant HF_REFANT
go clcal
wait clcal
IF HF_DEBUG = 1 THEN
read i
END
*
* == 8 CALIB: REAL cal (short solution intervals - 5s) for GETJY (SN=2) ==
*
print '*** 8 REAL CAL (SHORT INTERVALS - 5S) FOR GETJY (SN=2) ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
calsour HF_PRIMCL ''
calcode HF_CALCO
solint 5/60
docal 2
gainuse 2
snver 2
solmod 'a&p'
refant HF_REFANT
soltype 'L1R'
$ aparm 5 0 0 0 0 0 4 0
$ aparm 4 0 0 0 0 0 3 0
aparm 4 0 0 0 0 0 4 0
bif HF_BIF
eif HF_EIF
IF HF_DOBP = 1 THEN
doband 3
ELSE
doband -1
END
* Calibrate flux calibrator
go calib
wait calib
calcode ''
IF HF_DEBUG = 1 THEN
read i
END
* Calibrate complex gain calibrator(s)
cals HF_PHASC1 HF_PHASC2 ''
uvrang HF_CUVRAN 0
go calib
wait calib
IF HF_DEBUG = 1 THEN
read i
END
* Reset adverbs
uvrang 0
*
* == 9 GETJY ==
*
print '*** 9 GETJY ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
calsour HF_PRIMCL ''
calcode HF_CALCO
source HF_PHASC1 HF_PHASC2 ''
aparm 0
snver 2
bif HF_BIF
eif HF_EIF
go getjy
wait getjy
IF HF_DEBUG = 1 THEN
read i
END
* Reset adverbs
calcode ''
*
* == 10 CALIB: REAL cal (scan average, SOLINT=0) for source (SN=3) ==
*
print '*** 10 REAL CAL (SCAN AVE, SOLINT=0) FOR SOURCE (SN=3) ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
calsour HF_PRIMCL ''
calcode HF_CALCO
solint 0
docal 2
gainuse 2
snver 3
solmod 'a&p'
refant HF_REFANT
soltype 'L1R'
$ aparm 5 0 0 0 0 0 4 0
$ aparm 4 0 0 0 0 0 3 0
aparm 4 0 0 0 0 0 4 0
cparm(5) = HF_AMPSC
bif HF_BIF
eif HF_EIF
IF HF_DOBP = 1 THEN
doband 3
ELSE
doband -1
END
* Calibrate Flux Calibrator
print '*** 10.1 Primary Flux Calibrator ***'
go calib
wait calib
calcode ''
IF HF_DEBUG = 1 THEN
read i
END
* Calibrate Complex Gain Calibrator(s)
print '*** 10.2 Complex Gain Calibrator ***'
cals HF_PHASC1 HF_PHASC2 ''
uvrang HF_CUVRAN 0
go calib
wait calib
IF HF_DEBUG = 1 THEN
read i
END
* Reset adverbs
uvrang 0
cparm(5) 0
*
* == 11 CLCAL: Calibrate calibrators (using SN=3) ==
*
print '*** 11 CALIBRATE CALIBRATORS (USING SN=3) ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
calsour HF_PRIMCL HF_PHASC1 HF_PHASC2 ''
source HF_PRIMCL HF_PHASC1 HF_PHASC2 ''
interpol 'self'
opcode 'cali'
bif HF_BIF
eif HF_EIF
snver 2
inver 2
gainver 2
gainuse 3
refant HF_REFANT
go clcal
wait clcal
IF HF_DEBUG = 1 THEN
read i
END
*
* == 12 CLCAL: Calibrate source (using SN=3) ==
*
print '*** 12 CALIBRATE SOURCE (USING SN=3) ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
source HF_SRC ''
IF HF_USEALL = 1 THEN
cals HF_PHASC1 HF_PHASC2 ''
ELSE
cals HF_PHASC1 ''
END
opcode 'cali'
interpol '2pt'
samptype 'box'
bparm HF_CLSMO HF_CLSMO HF_CLSMO HF_CLSMO HF_CLSMO 0
$ bparm 1 1 1 1 1 0
snver 3
inver 3
gainver 2
gainuse 3
bif HF_BIF
eif HF_EIF
refant HF_REFANT
go clcal
wait clcal
IF HF_DEBUG = 1 THEN
read i
END
* Resetting adverbs
bparm 0
*
* == 13 Do Polarization Calibration? ==
*
IF HF_DOPCAL = 1 THEN
print '*** 13 DOING POLARIZATION CALIBRATION ***'
*
* == 13.1 RLDLY ==
*
* Note, this creates a new CL table from 3 to 4.
*
print '*** 13.1 RLDLY ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
calsour HF_PRIMCL ''
calcode HF_CALCO
timer 0 00 00 01 9 23 59 59
refant HF_REFANT
bchan HF_BCHAN
echan HF_ECHAN
docal 2
gainuse 0
solint HF_RECINT
IF HF_DOBP = 1 THEN
doband 3
ELSE
doband -1
END
go rldly
wait rldly
IF HF_DEBUG = 1 THEN
read i
END
* Resetting adverbs
timer 0
calcode ''
*
* == 13.2 PCAL ==
*
print '*** 13.2 PCAL ***'
* Continuum
inna HF_MULTIN
incl HF_MULTIC
inse 1
cals HF_PHASC1 HF_PHASC2 ''
bif HF_BIF
eif HF_EIF
bif 0
eif 0
refant HF_REFANT
soltype 'APPR'
domodel -1
spectral -1
docal 2
gainuse 0
IF HF_DOBP = 1 THEN
doband 3
ichansel HF_BCHAN HF_ECHAN 1 0
END
cparm 0,1
go pcal
wait pcal
IF HF_DEBUG = 1 THEN
read i
END
* Spectral Line
IF HF_DOBP = 1 THEN
spectral 1
doband 3
*=== CHECK THAT WE SHOULD USE ICHANSEL FOR SPECTRAL CASE
ichansel HF_BCHAN HF_ECHAN 1 0
go pcal
wait pcal
IF HF_DEBUG = 1 THEN
read i
END
END
* Resetting adverbs
ichansel 0
doband -1
cparm 0
*
* == 13.3 RLDIF ==
*
print '*** 13.3 RLDIF ***'
* Continuum
inna HF_MULTIN
incl HF_MULTIC
inse 1
source HF_PRIMCL ''
calcode HF_CALCO
bif HF_BIF
eif HF_EIF
bchan HF_BCHAN
echan HF_ECHAN
refant HF_REFANT
docal 2
gainuse 0
dopol 1
IF HF_DOBP = 1 THEN
doband 3
END
doapply 1
docrt 0
spectral 0
go rldif
wait rldif
IF HF_DEBUG = 1 THEN
read i
END
* Spectral Line
IF HF_DOBP = 1 THEN
spectral 1
docal 2
gainuse 0
doband 3
go rldif
wait rldif
IF HF_DEBUG = 1 THEN
read i
END
END
* Resetting adverbs
doband -1
dopol -1
calcode ''
ELSE
print '*** 13 SKIPPING POLARIZATION CALIBRATION ***'
END
*
* == 14 Remove any left over SPLIT files ==
*
print '*** 14 REMOVE ANY LEFT OVER SPLIT FILES ***'
inna HF_OUTN
incl 'SPLIT'
intype 'UV'
inse 0
alldest
$ YES
*
* == 15 SPLIT: SPLIT source from multisource data ==
*
print '*** 15 SPLIT SOURCE FROM MULTISOURCE DATA ***'
inna HF_MULTIN
incl HF_MULTIC
inse 1
docal 2
bif HF_BIF
eif HF_EIF
IF HF_DOBP = 1 THEN
doband 3
ELSE
doband -1
END
IF HF_DOPCAL = 1 THEN
dopol 1
ELSE
dopol -1
END
sources HF_SRC ''
aparm 0
bchan HF_BCHAN
echan HF_ECHAN
nchav 0
ichansel 0
go split
wait split
IF HF_DEBUG = 1 THEN
read i
END
* Rename
inna HF_SRC
incl 'SPLIT'
inse 1
outna HF_OUTN
outse 1
rena
* Resetting adverbs
dopol -1
outna ''
bpver 0
doband -1
*
* DO IMAGING AND SELFCAL?
*
IF HF_DOIMAG = 1 THEN
*
* == 16 CALIB: Phase-only point source selfcal on source ==
*
print '*** 16 PHASE-ONLY POINT SOURCE SELFCAL ON SOURCE ***'
inna HF_OUTN
incl 'CALIB'
intype 'UV'
inse 1
alldest
$ YES
incl 'SPLIT'
inse 1
outse 1
snver 0
cals ''
ichansel 1, HF_ECHAN-HF_BCHAN+1, HF_ECHAN-HF_BCHAN+1, 0
uvrange HF_UVRANG 0
solint HF_SOLINT
solsub HF_SOLSUB
solmod 'p'
smodel 1 0
bif HF_BIF
eif HF_EIF
refant HF_REFANT
soltype 'L1R'
docal -1
go calib
wait calib
IF HF_DEBUG = 1 THEN
read i
END
*
* == 17 IMAGR: Image data after phase-only point source selfcal ==
*
print '*** 17 IMAGE DATA AFTER PHASE-ONLY POINT SOURCE SELFCAL ***'
inna HF_OUTN
incl 'IBM001'
intype 'MA'
inse 1
alldest
$ YES
incl 'ICL001'
alldest
$ YES
incl 'CALIB'
cellsize HF_CELL
imsize HF_IMSIZE
source ''
inse 1
outse 1
uvrange 0
docal -1
dotv -1
bif HF_BIF
eif HF_EIF
niter HF_NITER
bchan HF_BCHAN
echan HF_ECHAN
nchav HF_ECHAN-HF_BCHAN+1
go imagr
wait imagr
IF HF_DEBUG = 1 THEN
read i
END
* Resetting adverbs
outse 0
*
* == 18 CCMRG: Merge CC components ==
*
print '*** 18 MERGE CC COMPONENTS ***'
inna HF_OUTN
incl 'ICL001'
inver 1
outver 2
inse 1
go ccmrg
wait ccmrg
IF HF_DEBUG = 1 THEN
read i
END
*
* == 19 CALIB: Phase-only selfcal on source using CC ==
*
print '*** 19 PHASE-ONLY SELFCAL on SOURCE USING CC ***'
inna HF_OUTN
incl 'CALIB'
intype 'UV'
inse 2
alldest
$ YES
in2na inna
in2cl 'ICL001'
in2se 1
inse 1
outse 2
outver 0
bif HF_BIF
eif HF_EIF
ichansel 1, HF_ECHAN-HF_BCHAN+1, HF_ECHAN-HF_BCHAN+1, 0
uvrange HF_UVRANG 0
solint HF_SOLINT
solsub HF_SOLSUB
solmod 'p'
inver 2
ncomp HF_NEGCC-1, 0
cmodel 'comp'
smodel 0
go calib
wait calib
IF HF_DEBUG = 1 THEN
read i
END
* Resetting adverbs
clr2n
outse 0
inver 0
ncomp 0
*
* == 20 IMAGR: Image data after phase-only selfcal using CC source ==
*
print '*** 20 IMAGE DATA AFTER PHASE-ONLY CC SELFCAL ***'
inna HF_OUTN
incl 'IBM001'
intype 'MA'
inse 2
alldest
$ YES
incl 'ICL001'
alldest
$ YES
incl 'CALIB'
cellsize HF_CELL
imsize HF_IMSIZE
source ''
inse 2
outse 2
uvrange 0
docal -1
dotv -1
bif HF_BIF
eif HF_EIF
niter HF_NITER
bchan HF_BCHAN
echan HF_ECHAN
nchav HF_ECHAN-HF_BCHAN+1
go imagr
wait imagr
IF HF_DEBUG = 1 THEN
read i
END
* Resetting adverbs
outse 0
*
* == 21 CALIB: Amp & phase point source selfcal on source ==
*
print '*** 21 A&P POINT SOURCE SELFCAL ON SOURCE ***'
inna HF_OUTN
incl 'CALIB'
intype 'UV'
inse 3
alldest
$ YES
inse 2
outse 3
ichansel 1, HF_ECHAN-HF_BCHAN+1, HF_ECHAN-HF_BCHAN+1, 0
bif HF_BIF
eif HF_EIF
uvrange HF_UVRANG 0
solint HF_SOLINT
solsub HF_SOLSUB
solmod 'a&p'
smodel HF_SRCFLX 0
docal -1
go calib
wait calib
IF HF_DEBUG = 1 THEN
read i
END
*
* == 22 IMAGR: Image data after Amp & Phase point source selfcal ==
*
print '*** 22 Image data after A&P point source selfcal ***'
inna HF_OUTN
incl 'IBM001'
intype 'MA'
inse 3
alldest
$ YES
incl 'ICL001'
alldest
$ YES
incl 'CALIB'
cellsize HF_CELL
imsize HF_IMSIZE
source ''
inse 3
outse 3
uvrange 0
docal -1
dotv -1
bif HF_BIF
eif HF_EIF
niter HF_NITER
bchan HF_BCHAN
echan HF_ECHAN
nchav HF_ECHAN-HF_BCHAN+1
go imagr
wait imagr
IF HF_DEBUG = 1 THEN
read i
END
* Resetting adverbs
outse 0
END
* Resetting adverbs
bchan 0
echan 0
pdver 0
bpver 0
nchav 0
uvrang 0
ichansel 0
inse 0
inver 0
FINISH
-------------- next part --------------
; EVLACAL
;---------------------------------------------------------------
;! Calibrates and maps high frequency observations
;# PROCEDURE CALIBRATION
;-----------------------------------------------------------------------
;; Copyright (C) 1995-1997; 2001
;; Associated Universities, Inc. Washington DC, USA.
;;
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2 of
;; the License, or (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public
;; License along with this program; if not, write to the Free
;; Software Foundation, Inc., 675 Massachusetts Ave, Cambridge,
;; MA 02139, USA.
;;
;; Correspondence concerning AIPS should be addressed as follows:
;; Internet email: aipsmail at nrao.edu.
;; Postal address: AIPS Project Office
;; National Radio Astronomy Observatory
;; 520 Edgemont Road
;; Charlottesville, VA 22903-2475 USA
;-----------------------------------------------------------------------
;---------------------------------------------------------------
EVLACAL LLLLLLLLLLLLUUUUUUUUUUUU CCCCCCCCCCCCCCCCCCCCCCCCCCCCC
EVLACAL: Procedure to run CALIB and LISTR for VLA calibration.
Use RUN HFCAL first!!!
HF_MULTIN UV file name (name)
HF_MULTIC UV file name (class)
HF_PRIMCL Primary flux calibrator
HF_CALCO Primary flux calibrator calcod
HF_PHASC1 Phase calibrator (fast switch)
HF_PHASC2 Phase calibrator (secondary)
HF_BPCAL Bandpass calibrator(s)
HF_SRC Source
HF_OUTN Output name (CAN'T=HF_SRC!)
HF_REFANT Reference antenna
HF_SOLINT Sol interval (min) for selfcal
HF_SOLSUB Sol subinterval (min) for scal
HF_RECINT Record interval(sec) for RLDLY
HF_DOIMAG Do imaging and selfcal?
HF_CELL Cellsize
HF_IMSIZE Imsize
HF_SRCFLX Source flux
HF_NEGCC First negative clean component
HF_NITER Clean iterations
HF_BIF First IF
HF_EIF Last IF
HF_BCHAN Low freq. channel
HF_ECHAN Highest freq channel
HF_DOPCAL Do polarization calibration?
HF_DOBP Do bandpass cal (-1=Cont Data)
HF_ANGEXP L-R phase diff for cal (3C286)
HF_CLSMO Boxcar width in CLCAL (hr)
HF_UVRANG Min UV range for Sgr A selfcal
HF_CUVRAN Min UV range for phase cal
HF_USEALL Use both cals in phase-pol cal
HF_AMPSC Use ampscalar averaging
HF_DEBUG Run EVLACAL in debug mode
----------------------------------------------------------------
HFCAL
Procedure: This procedure is designed to simplify the determining
antenna based calibration for calibrating high frequency
VLA data from external calibrator sources. It accepts a subset
of the input adverbs for CALIB and uses the default values for
the rest.
Before attempting to use HFCALP the RUN file
HFCALP must be run to define the adverbs used and to
read in the procedure. This is done by:
>RUN HFCALP
and only needs be done once.
Adverbs:
HF_MULTIN..Input UV file name (name). Standard defaults.
HF_MULTIC..Input UV file name (class). Standard defaults.
HF_PRIMCL..Primary Flux Calibrator (e.g., 3C286)
HF_CALCO...Primary flux calibrator calcode. ' '=>all
HF_PHASC1..Phase Calibrator (e.g., fast switch). If there
only one phase calibrator, enter it here.
HF_PHASC2..Phase Calibrator (e.g., secondary). If there is
only one phase calibrator, leave this blank.
HF_BPCAL...Bandpass calibrator(s). Used if HF_DOBP=1.
HF_SRC.....Source name (from LISTR).
HF_OUTN....Output name for maps.
HF_SOLINT..Solution interval (min).
HF_SOLSUB..Solution subinterval (min).
HF_RECINT..Record interval(sec) for RLDLY (0==> from data).
HF_REFANT..Reference antenna. If CALIB complains that it
cannot reference the solutions to it's chosed
antenna, leave this blank. If CALIB complains,
then chose a reference antenna close the center
of the array that is on-line throughout the run.
HF_DOIMAG..Do imaging and selfcal? (0 => no, 1 => yes)
If no, then stop after initial calibration leaving
SPLIT file.
HF_CELL....Cellsize for imaging in arcseconds.
HF_IMSIZE..Imsize for imaging.
HF_SRCFLX..Source flux for amplitude self-calibration.
HF_NEGCC...First negative clean component for CC model
self-calibration.
HF_NITER...Clean iterations for IMAGR.
HF_BIF.....First IF.
HF_EIF.....Last IF.
HF_BCHAN...Low freq channel.
HF_ECHAN...Highest freq channel.
HF_DOBP....Do bandpass calibration?
(0 => no, 1 => yes, -1 => no channel data)
HF_DOPCAL..Do polarization calibration? (0 => no, 1 => yes)
HF_ANGEXP..L-R phase difference for calibrator.
1331+305(3C286): All Bands = 66 deg.
0137+331(3C48): K = -146 deg, Q = -172 deg.
0521+1638(3C138): Q = -18 deg (-24 deg at higher freq).
HF_CLSMO...Boxcar width (hr) in CLCAL.
HF_UVRANG..Min UV range for Sgr A selfcal.
HF_CUVRAN..Min UV range for phase cal.
HF_USEALL..Use both cals in phase-pol cal.
HF_AMPSC...Use ampscalar averaging in final CALIB used to apply to
the source.
HF_DEBUG...Run EVLACAL in debug mode, stop waiting for user input
after each task. Enter any NUMBER to continue,
CHARACTER to end.
----------------------------------------------------------------
HFCALP: Procedure to run CALIB with fewer inputs and
possibly print the results with PRTMSG and LISTR.
Documenter: Doug Roberts
Related Programs: CALIB, LISTR, PRTMSG
More information about the Daip
mailing list